data_service.idl

#ifndef __TECGRAF_OPENBUS_DATA_SERVICE_IDL__
#define __TECGRAF_OPENBUS_DATA_SERVICE_IDL__

module tecgraf {

module openbus {

module data_service {

typedef sequence<octet> OctetSeq;

typedef sequence<string> StringSeq;

typedef long long TimeStamp;

typedef OctetSeq DataKey;

typedef  sequence<DataKey> DataKeySeq;

exception UnknownViewInterface {
  string fName; 
};

exception UnknownViews {};

exception InvalidDataKey {
  DataKey fKey; 
};

exception InvalidPrototype {};

exception DataAccessDenied{};

exception DataNotFound {
  DataKeySeq fKey; 
};

exception ServiceFailure {};

struct Metadata {
  string fName; 
  any fValue;  
};
typedef sequence<Metadata> MetadataSeq; 
valuetype DataDescription {
  public DataKey fKey;  
  public string fName; 
  public StringSeq fViews; 
  public MetadataSeq fMetadata; 
};
typedef sequence<DataDescription> DataDescriptionSeq; 
abstract interface DataView {
  DataKey getKey();

  string getInterfaceName();
};
typedef sequence<DataView> DataViewSeq; 
valuetype UnstructuredData supports DataView {
  public DataKey fKey; 
  public string fHost; 
  public unsigned long fPort; 
  public OctetSeq fAccessKey; 
  public boolean fWritable; 
};

interface IHierarchicalNavigationDataService {
  DataDescriptionSeq getRoots() raises (ServiceFailure, DataAccessDenied);

  DataDescriptionSeq getChildren(in DataKey fKey) raises (ServiceFailure,
      InvalidDataKey, DataNotFound, DataAccessDenied);

  DataDescription getParent(in DataKey fKey) raises (ServiceFailure,
      InvalidDataKey, DataNotFound, DataAccessDenied);

  DataDescription getDataDescription(in DataKey fKey) raises (ServiceFailure,
      InvalidDataKey, DataNotFound, DataAccessDenied);

  DataView getDataView(in DataKey fKey, in string fViewInterface)
      raises (ServiceFailure, InvalidDataKey, DataNotFound,
      UnknownViewInterface, DataAccessDenied);

  DataViewSeq getDataViewSeq(in DataKeySeq fKeys, in string fViewInterface)
      raises (ServiceFailure, InvalidDataKey, DataNotFound, 
      UnknownViewInterface, DataAccessDenied);
};

interface IHierarchicalManagementDataService {
  DataKey createData(in DataKey fPrototype, in DataDescription fParentKey)
      raises (ServiceFailure, InvalidDataKey, DataNotFound, InvalidPrototype,
      DataAccessDenied);

  DataKey copyData(in DataKey fSourceKey, in DataKey fParentKey)
      raises (ServiceFailure, UnknownViews, InvalidDataKey, DataNotFound, 
      DataAccessDenied);

  void moveData(in DataKey fKey, in DataKey fNewParentKey)
      raises (ServiceFailure, UnknownViews, InvalidDataKey, DataNotFound, 
      DataAccessDenied);

  void updateData(in DataKey fKey, in DataKey fSourceKey)
      raises (ServiceFailure, UnknownViews, InvalidDataKey, DataNotFound, 
      DataAccessDenied);

  void deleteData(in DataKey fKey) raises (ServiceFailure, InvalidDataKey, 
      DataNotFound, DataAccessDenied);
};

interface IHierarchicalTransferDataService {
  DataKey copyDataFrom(in DataKey fSourceKey, in DataKey fParentKey)
      raises (ServiceFailure, UnknownViews, InvalidDataKey, DataNotFound, 
      DataAccessDenied);

  void updateDataFrom(in DataKey fKey, in DataKey fSourceKey)
      raises (ServiceFailure, UnknownViews, InvalidDataKey, DataNotFound, 
      DataAccessDenied);
};

interface IHierarchicalDataService : IHierarchicalNavigationDataService,
    IHierarchicalManagementDataService, IHierarchicalTransferDataService {
};

}; // data_service

}; // openbus

}; // tecgraf

#endif